;+
; Project
;           SolarB EIS
;
; Name
;           EIS_DR_PROCESS_SCI_STUDY
;
; Purpose
;           Function
;
; Category
;           Timeline planning (timeline)
;
; Author
;           John Rainnie (JAR) 23-May-2008
;
; Version
;           v0.1 07-Nov-2011
;                Added "SILENT" keyword to eis_compression call
;           v0.2 28-Aug-2012
;                Ensure TARGET keyword is input into "eis_compression"
;
;-
;______________________________________________________________________________
FUNCTION eis_dr_process_sci_study , tl

; Get study start_time -> st_st
st_dur    = 0.D                                ; uncomment
nRasters  = tl.science_component.nRasters      ; uncomment
olines    = STRARR(nRasters)
format    = '(A-3,A-20,A-20,F-7.4,A-1)'

FOR i = 0 , nRasters -1 DO BEGIN

    sra             = tl.science_component.studyRasters[i]
    ra_dur          = sra.ra_duration

    ; 23-Aug-2012 JAR: ensure target string goes into compression
    ra_vol          = eis_compression(sra , $
                         target = tl.science_component.target, /SILENT)
    
    nRepeats        = sra.ra_repeats
    ra_start        = sra.ra_start_time
    ra_stop         = sra.ra_stop_time
    ra_dr           = (ra_vol/(1024.^2)) / (ra_dur/1000.)
    st_dur          = st_dur + (ra_dur * nRepeats)

    ra_start_date   = anytim2cal(ra_start , form = 8 , /date)
    ra_start_time   = anytim2cal(ra_start , form = 8 , /time)
    ra_stop_date    = anytim2cal(ra_stop  , form = 8 , /date)
    ra_stop_time    = anytim2cal(ra_stop  , form = 8 , /time)

    ra_start_string = STRJOIN([ra_start_date , ra_start_time],'  ',/SINGLE)
    ra_stop_string  = STRJOIN([ra_stop_date  , ra_stop_time ],'  ',/SINGLE)

    ; Make string
    line_out = STRING(format=format                                  ,     $
                 ''                                                  ,     $
                 ra_start_string                                     ,     $
                 ra_stop_string                                      ,     $
                 ra_dr + (0.05 * ra_dr)                              ,     $
                 'S')

    IF (tl.time_component.recursive   EQ 1) THEN line_out = line_out + 'R'
    IF (tl.time_component.time_tagged EQ 1) THEN line_out = line_out + '*'

    olines[i] = line_out

ENDFOR

RETURN , olines

END