;+
; NAME
;          EIS_CHECK_CMDPLN
;
; PURPOSE
;          This function checks the CMDPLN directory is valid
;
; INPUTS
;          None
;
; WRITTEN
;          John A Rainnie, RAL, 16-Jul-2008
;
; HISTORY
;          v0.2 JAR 21-Aug-2008
;               Changed $HOME/cmdpln to $HOME/remote_planning/cp/cmdpln
;          v0.3 JAR 6-May-2009
;               In the interests of MS users, make directory checking
;               case-insensitive!
;
;-
;______________________________________________________________________________
FUNCTION eis_check_cmdpln , textID , wait_t

valid = 1B
mText = "Checking CMDPLN....................................."
WIDGET_CONTROL , textID , set_value = STRING(format="(A-50)",mText) , /APPEND

CASE IS_BLANK( GETENV('CMDPLN') ) OF
   1  :    BEGIN
               valid = 0B
               mText = "The CMDPLN environment variable is NOT set."
           END
   ELSE :  mText = "CMDPLN environment variable is set"
ENDCASE
WIDGET_CONTROL , textID , set_value = STRING(format="(A-4,A-50)","",mText) , /APPEND
WAIT , wait_t
IF (valid EQ 0) THEN RETURN , 0

; Should be $HOME/cmdpln. Check!
should_be = STRJOIN([GETENV('HOME'),'remote_planning','cp','cmdpln'],PATH_SEP(),/SINGLE)
; JAR 6-May-2009 - make directory checking case-insensitive
CASE ( STRLOWCASE(GETENV('CMDPLN')) NE STRLOWCASE(should_be) ) OF
   1    :  BEGIN
               valid    = 0B
               mText = "The cmdpln folder must be in your $HOME/remote_planning/cp folder."
           END
   ELSE :  mText = "CMDPLN environment variable is OK"
ENDCASE
WIDGET_CONTROL , textID , set_value = STRING(format="(A-4,A-50)","",mText) , /APPEND
WAIT , wait_t
IF (valid EQ 0) THEN RETURN , 0

CASE FILE_TEST( GETENV('CMDPLN') , /DIRECTORY) OF
   0    :  BEGIN
               valid    = 0B
               mText = "There is no $HOME/remote_planning/cp/cmdpln folder."
           END
   ELSE :  mText = "cmdpln directory exists OK"
ENDCASE
WIDGET_CONTROL , textID , set_value = STRING(format="(A-4,A-50)","",mText) , /APPEND
WAIT , wait_t
IF (valid EQ 0) THEN RETURN , 0

;
; Check latest, today and tomorrow folders exist
;
dir_name      = ["latest","today","tomorrow"]
FOR i = 0, N_ELEMENTS(dir_name) - 1 DO BEGIN

   dir = STRJOIN([GETENV('CMDPLN'),dir_name[i]] , /SINGLE , PATH_SEP())
   IF (FILE_TEST(dir) EQ 1) THEN BEGIN
       value = STRJOIN(['$CMDPLN/',dir_name[i], ' folder is OK'],/SINGLE)
       mText = STRING(format="(A-4,A-50)","",value)
       WIDGET_CONTROL , textID , set_value = mText , /APPEND
       WAIT , wait_t
   ENDIF ELSE BEGIN
       valid = 0B
       value = STRJOIN(['$CMDPLN/',dir_name[i], " folder doesn't exist!"],/SINGLE)
       mText = STRING(format="(A-4,A-50)","",value)
       WIDGET_CONTROL , textID , set_value = mText , /APPEND
       WAIT , wait_t
       RETURN , 0
   ENDELSE
ENDFOR


RETURN , valid

END