FUNCTION eis_get_string_study , st , saved = saved

; We need - 
; acronym
; title
; author
; date - current
; nLines

;
; ID
;
IF (KEYWORD_SET(saved) EQ 1) THEN id = st.id ELSE id = -1
;
; Title
;
title_length = STRLEN(STRTRIM(st.title,2))
title_format = STRJOIN(["(A-24,A-",STRCOMPRESS(title_length,/REMOVE),")"],/SINGLE)
;
; Slit Slot
;
slit_slot = STRJOIN(STRTRIM(st.slit_slot , 2) , ',' , /SINGLE)
;
; XRT Flare
;
respond_flag = st.xrt_flare_response.respond_to_xrt_flare
response_id  = st.xrt_flare_response.response_study_id
x_repoint    = st.xrt_flare_response.x_repoint
y_repoint    = st.xrt_flare_response.y_repoint
raster_index = st.xrt_flare_response.repoint_raster_index
fov	     = st.xrt_flare_response.xrt_flare_in_FOV
follow_on_id = st.xrt_flare_response.follow_on_study_id
xrtF_line    = STRJOIN(STRTRIM([respond_flag,response_id,x_repoint,         $
                                y_repoint,raster_index,fov,                 $
                                follow_on_id],2), ',',/SINGLE)

;
; EIS Flare Response
;
respond_flag = st.eis_flare_response.respond_to_eis_flare
response_id  = st.eis_flare_response.response_study_id
x_repoint    = st.eis_flare_response.x_repoint
y_repoint    = st.eis_flare_response.y_repoint
raster_index = st.eis_flare_response.repoint_raster_index
eisF_line    = STRJOIN(STRTRIM([respond_flag,response_id,x_repoint,         $
                                y_repoint,raster_index],2), ',',/SINGLE)

;
; EIS Event Response
;
respond_flag = st.eis_event_response.respond_to_eis_event
response_id  = st.eis_event_response.response_study_id
x_repoint    = st.eis_event_response.x_repoint
y_repoint    = st.eis_event_response.y_repoint
raster_index = st.eis_event_response.repoint_raster_index
eisE_line    = STRJOIN(STRTRIM([respond_flag,response_id,x_repoint,         $
                                y_repoint,raster_index],2), ',',/SINGLE)

;
; AEC_response
;
aec = STRCOMPRESS(FIX(st.aec_response.respond_to_aec),/REMOVE_ALL)

;
; Date
;
date = STRTRIM(anytim2utc(systim(),/STIME,/DATE),2)

;
; Top Level
;
r     = STRARR(20)
tags  = TAG_NAMES(st)


; OK, here we go
r[0 ] = 'EIS_STUDY_START'
r[1 ] = STRING(format='(A-24,I-6)'  , tags[00] , id            )
r[2 ] = STRING(format='(A-24,A-20)' , tags[03] , st.acronym    )
r[3 ] = STRING(format=title_format  , tags[04] , st.title      )
r[4 ] = STRING(format='(A-24,I-6)'  , tags[05] , st.type       )
r[5 ] = STRING(format='(A-24,A-20)' , tags[06] , st.target     )
r[6 ] = STRING(format='(A-24,A-20)' , tags[07] , st.author     )
r[7 ] = STRING(format='(A-24,A-20)' , tags[08] , st.category   )
r[8 ] = STRING(format='(A-24,A-20)' , tags[09] , date          )
r[9 ] = STRING(format='(A-24,I-20)' , tags[11] , st.duration   )
r[10] = STRING(format='(A-24,I-20)' , tags[12] , st.volume     )
r[11] = STRING(format='(A-24,I-2)'  , tags[13] , st.nRasters   )
r[12] = STRING(format='(A-24,I-2)'  , tags[14] , st.recursive  )
r[13] = STRING(format='(A-24,A-20)' , tags[15] , slit_slot     )
r[14] = STRING(format='(A-24,A-30)' , tags[16] , xrtF_line     )
r[15] = STRING(format='(A-24,A-30)' , tags[17] , eisF_line     )
r[16] = STRING(format='(A-24,A-30)' , tags[18] , eisE_line     )
r[17] = STRING(format='(A-24,A-30)' , tags[19] , aec           )
r[18] = STRING(format='(A-24,I-2 )' , tags[20] , st.nRasters   )
r[19] = 'EIS_STUDY_END'


RETURN , TRANSPOSE(STRTRIM( r , 2))

END