;+
; Project     : SOLAR-B - EIS
;
; Name        : EIS_CPT_DATAVOL_ITEM_OUTPUT
;
; Purpose     : Outputs a data rate item.
;
; Explanation : Outputs a data rate item.
;
; Use         : < eis_cpt_datavol_item_output, text, vol, dr, eis_vol, item >
;
; Inputs      : text     : STRARR of text
;               vol      : FLOAT data volume in Mbits generated between contacts
;               dr       : FLOAT cumulative data volume in Mbits
;               eis_vol  : LONG data recorder limit in Mbits.
;               item     : STRUCTURE containing contact period info
;
; Opt. Inputs : None.
;
; Outputs     : text     : STRARR of text
;
; Opt. Outputs: None.
;
; Keywords    : FORMAT    : INT flag indicating should write the format used.
;
; Calls       : None.
;
; Common      : None.
;
; Restrictions: None.
;
; Side effects: Returns to calling routine if error.
;
; Category    : EIS_CPT.
;
; Prev. Hist. : None.
;
; Written     : Martin Carter RAL 10/10/05
;
; Modified    : Version 0.0, 10/10/05, MKC
;               Version 0.1, 17/09/06, MKC
;                 Changed pass ID to 4 characters.
;               Version 0.2, 03/10/06, MKC
;                 Changed item structure.
;                 Removed AFTER, NOCONTACT, NOPLAN, PERIOD keywords.
;                 Renamed from eis cpt datarate item output.
;
; Version     : 0.2, 03/10/06
;-
;**********************************************************

PRO eis_cpt_datavol_item_output, text, vol, dr, eis_vol, item, FORMAT=format

  ; check if format required

  IF KEYWORD_SET(format) THEN BEGIN

    eis_cpt_add, text, STRING('STA',  'DATE',    'TIME',   'DUR',   'EIS',     'VOL',     'DR', $
                FORMAT='("/*",1X,A3,  4X,A4,1X, 3X,A4,1X,  2X,A3,  3X,A3,1X,  4X,A3,   6X,A2,6X, "*/")')

    eis_cpt_add, text, STRING(             '(UT)',        '(sec)', '(Mbit)',  '(Mbit)',  '(Mbit)', $
                FORMAT='("/*",1X,3X,      8X,A4,5X,        1X,A5,   1X,A6,    1X,A6,    2X,A6,5X, "*/")')

    eis_cpt_add, text, '/*------------------------------------------------------*/'

  ENDIF ELSE BEGIN

    perc = 100*dr/eis_vol

    IF perc GT 100 THEN perc = '>100%' ELSE perc = STRING(perc,FORMAT='(I3,"%")')

    eis_cpt_add, text, STRING(item.res_name, $
                              eis_cpt_timeformat(item.start_time,/JSIDE), $
                              eis_cpt_timeformat(item.start_time,/HHMMSS), $
                              item.stop_time-item.start_time, $
                              item.eis_size, $
                              vol, dr, perc, $
                     FORMAT='(3X,A3,    1X,A8,   1X,A6,    2X,I4,   1X,I5,1X,   2X,I5, 3X,I5,  1X,A )')

  ENDELSE

END