;+
; Project     :	SOLAR-B - EIS
;
; Name        :	EIS_CPT_NOW
;
; Purpose     :	Returns current time.
;
; Explanation : Returns current time in different CDS formats.
;               Default is string format dd/mmm/yy hh:mm:ss.
;
; Use         :	< time = eis_cpt_now() >
;
; Inputs      :	None.
;
; Opt. Inputs : None.
;
; Outputs     : time : CDS TIME containing current time.
;
; Opt. Outputs:	None.
;
; Keywords    : CCSDS : FLAG indicating return time in CCSDS STRING format.
;               UTC   : FLAG indicating return in UTC format
;               TAI   : FLAG indicating return in TAI format
;               DATE  : FLAG indicating return DATE only.
;               FORM  : INT specifies a format for STRING date.
;                           0           dd/mmm/yy hh:mm:ss  [default]
;                           1           dd-mmm-yy hh:mm:ss
;                           2           dd/mm/yy  hh:mm:ss
;                           3           dd-mm-yy hh:mm:ss
;                           4           mm/dd/yy hh:mm:ss
;                           5           mm-dd-yy hh:mm:ss
;                           6           yy/mm/dd hh:mm:ss
;                           7           yy-mm-dd hh:mm:ss
;                           8           yyyymmddhhmmss
;                           9           dd-mmm-yyyy hh:mm:ss.sss (VMS-like)
;                          10           dd-mmm-yyyy hh:mm:ss.ss (!stime-like)
;                          11           yyyy/mm/dd hh:mm:ss.sss (cpt use)
;
; Calls       : None.
;
; Common      :	None.
;
; Restrictions:	None.
;
; Side effects:	None.
;
; Category    :	EIS_CPT.
;
; Prev. Hist. :	None.
;
; Written     :	Martin Carter RAL 04/11/04
;
; Modified    :	Version 0.1, 07/02/05, MKC
;                 Added FORM keyword.
;               Version 0.2, 09/03/05, MKC
;                 Added TIMESTAMP keyword.
;               Version 0.3, 24/03/05, MKC
;                 Removed TIMESTAMP keyword.
;
; Version     :	Version 0.3, 24/03/05
;-
;**********************************************************

FUNCTION eis_cpt_now, CCSDS=ccsds, DATE=date, UTC=utc, TAI=tai, FORM=form

  ; get current time

  get_utc, now

  ; convert to calendar time or CCSDS time

  IF KEYWORD_SET(utc) THEN BEGIN

    IF KEYWORD_SET(date) THEN now.time = 0

    RETURN, now

  ENDIF ELSE IF KEYWORD_SET(tai) THEN BEGIN

    IF KEYWORD_SET(date) THEN now.time = 0

    RETURN, anytim2tai(now)

  ENDIF ELSE IF KEYWORD_SET(ccsds) THEN BEGIN

    RETURN, anytim2utc(now, /CCSDS, DATE=date)

  ENDIF ELSE BEGIN

    RETURN, anytim2cal(now, DATE=date, FORM=form)

  ENDELSE

END