pro eis_fits_produce, md_dir = md_dir, fits_dir = fits_dir
; script to create fits files from a list of lines
; Outputs: Fits file
;
; Oivind Wikstol 13-April-2005
;

if n_elements(md_dir) eq 0 then md_dir = '/data/eis/fm/data/devel/'
if n_elements(fits_dir) eq 0 then $
  fits_dir = '/home/solarb/eis/data/science/fits/'

; add dirsep to end of md_dir if not there already:
dirsep=path_sep()
if strpos(md_dir,dirsep,/reverse_offset) ne strlen(md_dir)-1 then $
  md_dir = md_dir + dirsep

; add dirsep to end of fits_dir if not there already:
if strpos(fits_dir,dirsep,/reverse_offset) ne strlen(fits_dir)-1 then $
  fits_dir = fits_dir + dirsep

search_str = md_dir+'md*'
mdfiles=file_search(search_str,/fully_qualify_path)

for i=0, n_elements(mdfiles)-1 do begin
  ; create filename
  filesplit = strsplit(mdfiles[i], dirsep,/extract)
  nsplit = n_elements(filesplit)
  md_nr = strsplit(filesplit[nsplit-1],'.',/extract)
  md_nr = md_nr[n_elements(md_nr)-1]

  run_nr = strsplit(filesplit[nsplit-2],'.',/extract) 
  
  fitsfile = 'eis_'+run_nr+'_'+md_nr+'.fits'

  ; read md_file, planning tool info (if available) and produce fits file
  data=obj_new('eis_data', mdfiles[i], datasource='ccsds',hdr=hdr)

  exp_info = (hdr[0])->getexp_info()
  seq_id = exp_info.seq_id
  rast_id = exp_info.rast_id

  plan = obj_new('eis_plan', seq_id, rast_id)
  eis_mkfits, data, hdr, plan = plan, fitsdir=fits_dir, fitsfile=fitsfile
endfor

end