;+ ***********************************************************************
; NAME:
;	MOD_NRHFILE
;
; PURPOSE:
;	Cette fonction modifie le nom du fichier suivant le KEYWORD specifie
;
; CATEGORY:
;	Fichiers NRH
;
; CALLING SEQUENCE:
;	Newfile = MOD_NRHFILE( File )
;
; INPUTS:
;	FILE	Nom du fichier a modifier.
;	
; KEYWORD PARAMETERS:
;		Voir CW_NRHFILE pour la definition des codes
;	RESEAU	Nouveau code reseau
;
;	FREQ	Nouveau code frequence, unite 0.1MHz
;
;	HEURE	Nouvelle heure sous forme hh:mm:ss:ccc 
;				(telle que fournie par MSH)
;	INTERP	Nouveau code d'interpolation
;
;	DIVERS	Code du champ libre
;
;	CONTENT Nouveau code du type (images, harmoniques , flux,, etc...)
;
;	 ETAT	Nouveau code ETAT (acquisition, comprime
;
;	EXTEN   Extension du nom de fichier( *.fts, *.png)
;
;	DIRECTORY Modification du chemin
;
; OUTPUTS:
;	Nom de fichier modifie
;
; PROCEDURE:
;	You can describe the foobar superfloatation method being used here.
;	You might not need this section for your routine.
;
; EXAMPLE:
;	Newfile = MOD_NRHFILE ( file, CONTENT = 'f')
;	Modifie le code pour indiquer que le nouveau fichier est un fichier
;	de flux
;
; MODIFICATION HISTORY:
;	Ecrit par: J BONMARTIN le 13/02/98 (bonmartin@obspm.fr)
;		rajoute le KEYWORD EXTEN le 25/06/98
;	Le 02/04/99	Complete la chaine d'heure
;	Le 27/09/00 compatibilte Windows
;		change le separateur de centiemmes dans les noms : -> c
;		separateurs repertoires / ou \
;-*******************************************************************

FUNCTION MOD_NRHFILE, File, RESEAU = Reseau, DATE = date, $
	FREQ = Freq, HEURE = Heure, INTERP = Interp, DIVERS = Divers, $
	CONTENT = Content, ETAT = Etat, DIRECTORY = directory, EXTEN=exten

NEWFILE = File
	IF KEYWORD_SET (DIRECTORY) THEN BEGIN
		SEPD = '/'
		IF !VERSION.OS_FAMILY EQ 'Windows' THEN SEPD = '\'
		REPERT= STR_SEP( Newfile, Sepd)
		If DIRECTORY EQ 'Current' THEN $
			cd, CURRENT= directory
		Name = repert[((size(repert)) (1)) -1]
		NewFile = directory+ Sepd + Name
	END

	LEN = STRLEN(Newfile)
	PDEB = Len - 38

	IF KEYWORD_SET (RESEAU) THEN $
		STRPUT, Newfile, Reseau, PDEB + 3

	IF KEYWORD_SET (DATE) THEN $
		STRPUT, Newfile, Date, PDEB + 14

	IF KEYWORD_SET (FREQ) THEN $
		STRPUT, Newfile, Freq, PDEB + 5

	IF KEYWORD_SET (HEURE) THEN BEGIN
		IF STRLEN(HEURE) LT 12 THEN BEGIN  ;Complete l'heure
			HM=HMS(Heure) 
				Heure=MSH(Hm)
		END
		HR = STRMID(Heure,0,2) + STRMID(Heure,3,2) + $
			STRMID(Heure,6,2) +'c' + STRMID(Heure,9,2)	
		STRPUT, Newfile, Hr,	PDEB + 23
	END	

	IF KEYWORD_SET (INTERP) THEN $
		STRPUT, Newfile, Interp, PDEB + 11

	IF KEYWORD_SET (DIVERS) THEN $
		STRPUT, Newfile, Divers, PDEB + 12

	IF KEYWORD_SET (CONTENT) THEN $
		STRPUT, Newfile, Content, PDEB + 10

	IF KEYWORD_SET (ETAT) THEN $
		STRPUT, Newfile, Etat, PDEB + 33

	IF KEYWORD_SET (EXTEN) THEN $
		STRPUT, Newfile, Exten, PDEB + 35

RETURN, Newfile

END