;+ ***********************************************************************
; NAME:
;	NRH1_POSCRIPT
;
; PURPOSE:
; 	CETTE PROCEDURE PERMET DE GENERER DES FICHIERS POSTSCRIPT
;	
;
; CATEGORY:
;	NRH1 General
;
; CALLING SEQUENCE:
;	NRH1_POSTSCRIPT
;
; INPUTS:
;	Non
;	
; KEYWORD PARAMETERS:
; ON 	:	OUVRE LE DEVICE POSTSCRIPT
; OFF	:	PERMET DE PASSER EN MODE X
;			POUR CONTINUER A FAIRE DE 
;			L'AFFICHAGE SANS FERMER LE FICHIER POSTSCRIPT
; STOP	:	FERME LE FICHIER POSTSCRIPT
;		REPASSE EN MODE X
;
; OUTPUTS:
;	Non
;
; COMMON BLOCKS:
;	NRH1_HELIO
;
; EXAMPLE:
;	NRH1_POSTSCRIPT, /ON	;ouvre un fichier postscript
;	NRH1_POSTSCRIPT, /OFF	;ferme le fichier postscript
;
; MODIFICATION HISTORY: bonmartin@obspm.fr
;	Ecrit par:
; Modifications:
;		Possibilite de sortir en format paysage (nov 1997)
;		Ecriture date de generation du trace (21 Nov 1997)
;-*******************************************************************

PRO NRH1_POSTSCRIPT, on=on, off=off,stop=stop 

Common NRH1_HELIO,mainstruct

IF KEYWORD_SET(on) THEN BEGIN
  mainstruct.OldP=!p


  IF mainstruct.psorient EQ 0 THEN BEGIN
	xlong = 20.74
	ylong = 29.7 
	xoffset= .5 * (20.74 - xlong)
	yoffset= .5 * (29.7 - ylong)
  ENDIF ELSE BEGIN
	ylong = 20.74
	xlong = 29.7
	yoffset = 30.5 ; 29.5 bon pour ghostview, mais trop a droite pour ljps
	xoffset = 0.
  ENDELSE

  SET_PLOT,'ps'
  DEVICE,COLOR=mainstruct.pscouleur, LANDSCAPE=mainstruct.psorient,  $
	XSIZE=xlong, YSIZE=ylong, XOFFSET=xoffset, YOFFSET=yoffset, $
	BITS=8	; set POSTSCRIPT FILE to 8bits/color (OK pour PNG files);
;			cf. IDL Ref. Guide 3-42)

ENDIF 

IF KEYWORD_SET(off) THEN BEGIN
; Ecriture de la date de generation du trace
	crdat = SYSTIME(0)
	pos = RSTRPOS(crdat, ':')
	date = STRMID(crdat, 20, 4) + ' ' + STRMID(crdat, 4, pos-4)
	xyouts, .06, .03, 'Creation: ' + date ,$
			 charsize = .7, /normal
	xyouts,.5 , .03, $
		'Nançay Radioheliograph', ALIGNMENT=.5, /normal
  SET_PLOT,'x'
  !p=mainstruct.oldp
ENDIF

IF KEYWORD_SET(stop) THEN BEGIN  
   SET_PLOT,'ps'
   DEVICE,/CLOSE
   spawn,'mv idl.ps '+mainstruct.psfilename
   SET_PLOT,'x'
ENDIF

END