;+ ***********************************************************************
; NAME:
;	WD_NRH_ROUT
;
; PURPOSE:
;	Cette procedure contient les widgets pour le tarce des flux des 
;	routines afin de generer des images PNG pouvant servir a la
;	visualisation sur le WEB
;
; CATEGORY:
;	NRH Routine
;
; CALLING SEQUENCE:
;	WD_NRH_ROUT
;
; INPUTS:
;
;	
; KEYWORD PARAMETERS:
;	GROUP	Identification du Widget appelant	
;
; OUTPUTS:
;	
;
; OPTIONAL OUTPUTS:
;	
; COMMON BLOCKS:
;	
;
; SIDE EFFECTS:
;	Cette procedure prend le dernier fichier nrin*.pro disponible
;	dans le repertoire courant et boucle si aucun fichier n'est
;	disponible
;
; RESTRICTIONS:
;
; PROCEDURE:
;	Cette procedure appelle NRHR_PLOTI periodiquement et enregistre
;	le trace dans rout.png
;
; EXAMPLE:
;
; MODIFICATION HISTORY:
;	Ecrit par:J Bonmartin  (bonmartin@obspm.fr) le 11/10/00
;-*******************************************************************

PRO WD_NRH_ROUT_EVENT, Event

COMMON COM_WD_NRHR_PLOTI, COM, IDT, Wc, Itext

if tag_names(event,/structure_name) eq 'WIDGET_TIMER' THEN BEGIN
      IF COM EQ 1 THEN BEGIN
            WI= !D.Window &WSET,Wc
            NRHR_PLOTI, Ret
		IF RET NE -1 THEN BEGIN
		TVLCT,R,G,B,/GET
		Ima= TVRD()
		WRITE_PNG,'rout.png',ima,R,G,B
		ENDIF
            WSET , Wi
            WIDGET_CONTROL, Event.top, Timer= Idt
      ENDIF ELSE WIDGET_CONTROL, Itext, Set_Value=' Wait'
RETURN
ENDIF

WIDGET_CONTROL, event.id, get_uvalue= ev

case ev of
        'Start': BEGIN
            WI= !D.Window &WSET,Wc
           NRHR_PLOTI, Ret
		IF RET NE -1 THEN BEGIN
		TVLCT,R,G,B,/GET
		Ima= TVRD()
		WRITE_PNG,'rout.png',ima, R, G, B
		ENDIF
            WSET , Wi
           Com= 1
           WIDGET_CONTROL, Event.top, Timer=Idt
           WIDGET_CONTROL,Itext, SET_VALUE='Running'
           End
	'Idt':	Idt = Event.value
        'Stop': Com= 0
        'Exit': BEGIN
            WDELETE,Wc
            Com= 0
            WIDGET_CONTROL, Event.top, /DESTROY
            END
ENDCASE

END

PRO WD_NRH_ROUT, GROUP= Group

COMMON COM_WD_NRHR_PLOTI, COM, IDT,Wc, Itext

Com=0
IDT=10
IF NOT KEYWORD_SET(GROUP) THEN Group=0

Base = WIDGET_BASE(GROUP_LEADER= Group, TITLE = 'Routines NRH',$
           XSIZE= 200,/COLUMN)
      B= WIDGET_BUTTON(Base,UVALUE='Start', VALUE= 'START',XSIZE=40)
      B= WIDGET_BUTTON(Base,UVALUE='Stop', VALUE= 'PAUSE')
      B= WIDGET_BUTTON(Base, Uvalue='Exit', VALUE= 'EXIT')
      B= CW_FIELD(Base, Value= Idt, Uvalue= 'Idt',Title='Periodicity(s):', $
		/integer,/all_events,xsize=4)
      ITEXT = WIDGET_TEXT(Base, XSIZE=40,Value='Wait')

WINDOW,/FREE
WC = !D.Window

WIDGET_CONTROL, base, /REALIZE
XMANAGER,'WD_NRH_ROUT',Base,/NO_Block
END