PRO RH_LISTFREQ, str_yymm,repent=repent,repsor=repsor

;+ ***********************************************************************
; NAME: RH_LISTFREQ
;
; PURPOSE:
;    Cette procedure liste les frequences des manip RH du mois
;    Elle cree un fichier de nom freqyymm.lis
; CATEGORY:
;       Traitement de fichiers NRH.
;
; INPUTS:
;   STR_YYMM : chaine de carac. contenant yymm definissant le mois
;
; KEYWORDS:
;  REPENT  : repertoire des fichiers RH lus
;            par defaut /data/nancay
;  REPSOR  : repertoire 
;            par defaut repertoire courant
; MODIFICATION HISTORY:
;  A. Bouteille janvier 2003
;-*******************************************************************
    @rh_common.inc 
    if (n_params() lt 1)then begin
      print,' Cette procedure liste les frequences des manip RH du mois '
      print,'  pour des manip recentes stockees sur /data/nancay'
      print,' Elle cree un fichier de nom freqyymm.lis sur le repertoire '
      print,'  courant'
      print,' Erreur : parametre d''entree manquant'
      print,' lancer par sswidl'
      print,' rh_listfreq, "yymm",[repent=REPENT],[repsor=REPSOR]'
      print,' par defaut: repent=''/data/nancay/'',repsor=rep. local'
      return
    endif
    if not keyword_set(repent) then repent='/data/nancay/'
    if right(repent,1) ne '/' then repent=repent+'/'
    if not keyword_set(repsor) then repsor='./'
    if right(repsor,1) ne '/' then repsor=repsor+'/'
    openw,unit,repsor+'freq'+str_yymm+'.lis',/get_lun
    liste=findfile(repent+'2q'+str_yymm+'*',count=nc)
    if nc eq 0 then begin
        print,' ******  PAS DE FICHIERS '+repent+'2q',str_yymm,'*   STOP'
        stop
    endif
    for k = 0, n_elements(liste)-1 do begin
      fich = liste(k)
      if not (rh_open(fich,/mono)) then begin
        print ,'erreur ouverture',fich
        rh_close
        return
    endif
      nf = entfi.nf
      nc = strpos(fich,'/',/reverse_search)
      fichs = strmid(fich,strpos(fich,'/',/reverse_search)+1)
      chformat ='("RH",A13,2x,2(1x,i2.2,":",i2.2,":",i2.2,".",i2.2),2x,10F7.1)'
      print, fichs, entfi.hdeb, entfi.hfin, entfi.frq(0:nf-1)/10., $
          format = chformat
      printf, unit, fichs, entfi.hdeb, entfi.hfin, entfi.frq(0:nf-1)/10., $
          format = chformat
      rh_close  
  endfor
      close,unit
      free_lun, unit  
return
end