FUNCTION RH_NAME_FITS, res, freq, type, npew, integ, $
	 date, heure, compr
;+ ***********************************************************************
; NAME:
;	RH_NAME_FITS
;
; PURPOSE: 
;	Cette fonction cree le nom d'un fichier fits RH:
;	nrhr_ffff_hpg_yyyymmjj_hhmnss:cc_c.fts
; CATEGORY:
;	Traitement de fichiers NRH
; CALLING SEQUENCE:
;	RH_NAME_FITS, Res, Freq, Type, Npew, Integ, $
;	 Date, Heure, Compr
; INPUTS:	
;  Res	->	r reseau ew(e) ns(n) 1d(1) ou 2d(2)	string
;  Freq ->	ffff frequence en centaines de khz	integer
;  Type		i ou h ou p ou f 			string
;     	i = coordonnees instrumentales
;     	h = coordonnees heliographiques
;	a = harmoniques
;     	p = fichier de type positions
;     	f = fichier de type flux

;  Npew->	npew=2**p
;		p niveau d'interpolation de 0 a 9	integer
;  Integ->	g niveau d'integration de 0 a 9		integer
;  Date		date (jour, mois, an).	 		intarr(3)
;  Heure(4)->	heure de debut (h,m,s,c)		intarr(3)
;  Compr->	c ou d ou b	string 
;		fichier comprime(c) ou decomprime(d) ou brut(b)
; OUTPUTS:
;	nomfich = nom du fichier
;  EXAMPLE:
;	nomfich = RH_NAME_FITS('2', 1640, 'h', npew, 0, $
;			    [1996,10,21], [9,0,0,0], 'c')
;MODIFICATIONS:
;	Le 27/09/00 'c' en tant que separateur de centiemmes de secondes
;- ********************************************************************

    inter = 0
    if (npew  ne 0) then  inter = fix (alog(npew) / alog(2))
    if (inter gt 9) then  inter = 0   ; rajoute le 28 juin 04 pour le cas GMRT.
	; Rem : np1 n'est pas une puissance de 2 en general, c'est un nbre
	;	pair quelconque => inter sera tronque, mais il sera utilise
	;	uniquement pour creer le nom de fichier de sortie, duquel on
	;	n'extrait pas le nbre de points de l'image, qui figure exacte-
	;	ment dans le header. Donc on s'en fout.
    heurect = heure & heurect(3) = fix(heure(3)/10)
    ch_format = '("nrh", a1, "_", i4, "_", a1, 2(i1), "_", i4, 2i2.2, ' + $
	'"_", 3i2.2, "c", i2.2, "_", a1, ".fts")'
    return, string(format=ch_format,  res,  freq,  type,  inter,  integ, $
	rh_date100(date(2), /full), date(1), date(0),  heurect,  compr) 
	    ; rh_date100(date(2) est l'annee munie de 1900 ou 2000.
    end