pro rh_ecrhead_fits,uic,tab,nrec
;+
; NAME
;	RH_ECRHEAD_FITS
; PURPOSE:
;	ecriture du header FITS donnees 2D RH 
;	Les enregistrements sont de longueur 2880 octets
;	un mot-cle fits occupe une ligne de 80 octets
;       dans un record de 2880 octets on met 36 lignes de 80 octets 
; CALLING SEQUENCE:
;	ecrhead_fits,uic,tab
;
; INPUTS:
;	uic	: numero d'unite pour ecrire	INT
;	tab	: header		        STRARR(*)
;	nrec	: nb de records du header
; OUTPUTS:
;
; CALLS:
;
; MODIFICATION HISTORY:
;	ecrit par A.Bouteille (mars 1997)
;-
  nmot=n_elements(tab)
; chaine servant a completer par des blancs la ligne contenant le mot cle
  chaine=string(replicate(32b,80))
  nligne=0
; boucle sur les mot-cles fits
  for i=0,nmot-1 do begin
      ligne=chaine
      strput,ligne,tab(i),0
      writeu,uic,byte(ligne)
      nligne=nligne+1
  endfor
; remplissage du dernier record de 36 lignes par des blancs
  nl_rest=nmot MOD 36
  if nl_rest ne 0 then begin
      nl_blanc=36-nl_rest  
      for i=0,nl_blanc-1 do begin
          writeu,uic,byte(chaine)
          nligne=nligne+1
      endfor
  endif
  nrec=nligne/36
;  print,' HEADER FITS :',nrec,' records de 2880 octets
;  print,'              ',nmot,' mots cle',nligne,' lignes'
end