PRO RH_DP_INFO, nomfich, ch, hd, hf, ipol, npew,  $  
	dsmf, numcnt, taille_mega
;+ ***********************************************************************
; NAME:
;	RH_DP_INFO
; PURPOSE:
;	Cette procedure rassemble les informations pour le calcul des fichiers 
;	FITS Nrh 2D de sortie :
;	  - nom des fichiers, - nombre d'images attendu dans chaque frequence
;	    entre les heures hd et hf,
;	  - taille em megaoctets.
; CATEGORY:
;	Traitement de fichiers RH
; CALLING SEQUENCE:
;	RH_DP_INFO, nomfich, ch, hd, hf, ipol, npew,  $  
;	dsmf, numcnt, taille_mega	
; INPUTS:
;	nomfich	: nom du fichier RH d'entree
;	ch	: 
;	hd,hf	: heures de debut et de fin
;	ipol	: =0 NP seul , =1 NP+P
;	npew	: nb de points de l'image en EW et NS
; OUTPUTS: 
;	dsmf(entfi.nf)	: nom des fichiers FITS
;	numcnt(entfi.nf): nb d'images entre hd et hf
;	taille_mega(entfi.nf)	: taille de chaque fichier FITS
; COMMON BLOCKS:
;	RH	: communique avec les routines de lecture des donnees
;		  brutes RH	
; MODIFICATION HISTORY:
;	Ecrit par A. Bouteille
;-**************************************************************************

; Ouverture du fichier Nancay
    @rh_common.inc
    IF NOT RH_OPEN(NOMFICH,/mono) THEN begin
        print,'pb rh_open'
        RETURN
    endif

; si le mot cle SELEC est absent, on demande toutes les frequences
    if n_elements(ch) eq 0 then begin
        ch=strarr(10)
        ch(*)=replicate('Y',10)
        ch(entfi.nf:*)='N'
    endif

    temp=[3600000L,60000L,1000L,10L]
    msd=(transpose(temp)#long(hd))(0)
    msf=(transpose(temp)#long(hf))(0)
;
; selection des heures:
; calcul des indices des records de debut et de fin   
    RH_LECDEB, msd, msf, kdeb, kfin
; si klumax n'est pas une frequence selectionnee, on demande a lire
; une frequence au dela de klumax et on tombe sur EOF
    isel=where(ch eq 'Y')
    nsel=n_elements(isel)
    if ( kfin eq entfi.klumax) then kfin=entfi.klumax-entfi.nf+isel(nsel-1)+1
;    print,'kfin,klumax',kfin,entfi.klumax

    klu=kdeb
    RH_READCH, klu, ch
;   print,' hedebut',bfi.h
; 
;   Type du fichier typ1 '1' ou '2'   typ2 'd', 'c', 'i' ou 'q'
    RH_FICH_CTR, nomfich, path, typ1, typ2
; si donnees brutes le type est 'b'
; le type 'd' est reserve aux donnees decomprimees
    if typ2 eq 'd' then typ2 = 'b'
    integ=0   
    dsmf=strarr(entFI.nf)
    for nf=0,entFI.nf-1 do begin
        if ch(nf) eq 'Y' then begin
            dsmf(nf)= rh_name_fits('2', entfi.frq(nf), 'h', npew, integ, $
		entfi.dat, bfi.h, typ2)
        endif  
    end

; calcul du nb d'acq pour chaque frequence entre kdeb et kfin. Ce nb varie
;  pour les differentes freq. du fait de la compression.
;  numcnt est lonarr(entfi.nf) 
; pour eviter une attente trop longue des infos, on fait un calcul approche
;  du nb d'images de chaque frequence dans le cas des gros fichiers
; calcul approche :
    numcnt = lonarr(entfi.nf)
    numcnt(*) = (kfin-kdeb+1L)/long(entfi.nf)
;   print,'nb approche',numcnt
; calcul exact : on compte les acq entre kdeb et kfin
    if(numcnt(0) lt 500l)then begin
        RH_FRQCNT, kdeb, kfin, numcnt
;       print,'nb exact',numcnt
    endif
    taille_mega = (long(numcnt)* npew* npew/1024.)   $
		  *(ipol+1)*4./1024.
    end