;+ ***********************************************************************
; NAME:
;	READ_CENTER_POINT
;
; PURPOSE:
;	Cette procedure lit les valeurs associee a une source d'un fichier
;	de CENTRES ACTIFS (Sources)
;
; CATEGORY:
;	Cfile
;
; CALLING SEQUENCE:
;	NRH_READ_CENTER, File, Extd, Str
;
; INPUTS:
;	FILE	Nom du fichier
;
;	EXTD	Numero de l'extension dans le fichier CENTRES 
;

; KEYWORD PARAMETERS:
;	HBEG	Heure de debut selectionnee (HH:MN:SS:MMM)
;
;	HEND	Heure de fin selectionnee
;	
; OUTPUTS:
;	STR	structure contenant les valeurs associee a la source
;		Cette structure est cree dans la procedure
;			STR.Time	Heure
;			STR.Flux	Flux
;			STR.EWPOS	Position est-ouest
;			STR.NSPOS	Position nord_sud
;
; COMMON BLOCKS:
;	Non
;
; RESTRICTIONS:
;	Seuls les fichiers CENTRE ACTIF calcules dans NRH peuvent etre traites
;
; PROCEDURE:
;	Le numero de l'extension du fichier FITS peut etre determinee en
;	appelant CW_XTD_NRHF
;
; EXAMPLE:
;	Please provide a simple example here
;
; MODIFICATION HISTORY:
;	Ecrit par:J Bonmartin (bonmartin@obspm.fr) le 12/10/98
;-*******************************************************************

PRO NRH_READ_CENTER, File, Extd, Centre, HBEG=Hbeg, HEND = Hend 


	FXBOPEN,UNIT,File,Extd,Header
		XCEN = FXPAR(Header, 'CRPIX1')
		YCEN = FXPAR(Header, 'CRPIX2')
		RAY = FXPAR(HEADER, 'SOLAR_R')

	FXBREAD,Unit, Time, 'TIME'
		IF NOT KEYWORD_SET(HBEG) THEN IND = 0 $
			ELSE IND= TIME_IND( Time, HMS(Hbeg))
		IF NOT KEYWORD_SET(HEND) THEN INF = N_ELEMENTS(Time)-1 $
			ELSE INF= TIME_IND( Time, HMS(Hend))

	SZ= Inf -Ind +1
CENTRE = {Time:LONARR(sz), Flux: Fltarr(sz), Ewpos: Fltarr(sz), $
		NSPOS:fltarr(sz)} 	

	FXBREAD, Unit, Xpos, 'EWPOS'
	FXBREAD, Unit, Ypos, 'NSPOS'
	FXBREAD, Unit, Flux, 'FLUX'

	FOR I = Ind , Inf DO BEGIN
		Centre.Ewpos(i-ind) = Ind_rs(Xpos(I), Xcen, Ray)
		Centre.Nspos(i-ind) = Ind_rs(Ypos(I), Ycen,Ray)
		Centre.Flux(i-ind) = Flux(I)
		Centre.Time(i-ind) = (Time(i))
	END

	FXBCLOSE, Unit	

END