pro listpos, tabpos, posinfo, pastempo, heures=heures, numpos=numpos, $
	title=title

; procedure de listing des parametres de sources localisees

;     Parametres d'entree :
;                   tabpos ...... Tableau issu de LECP1D ou LECP1D contenant 
;			    les images
;                           tabpos(Num_position,type,indice temporel)
;					type = parametre de la source
;                   posinfo...... Tableau 2D contenant, pour chaque position: 
;					heure debut [ms] (posinfo(0, numero))
;					nbre de points (posinfo(1, numero))
;                   pastempo .... Intervalle de temps entre deux enreg. [ms]
;                   heures   .... Heures debut, fin a lister [ms]
;                   numpos ...... Numero de la position a lister (= 1 pour la
;					premiere position)
;				    si non donne, affiche toutes les positions
;                                   =-1 a la sortie si position n'existe pas
;		    title ....... Tableau de caracteres decrivant les 
;					parametres affiches
; 
;* -------------------------------------------- *
;*     Declaration des variables globales       *
;* -------------------------------------------- *
;
   COMMON global,nomfich,FichInfo

b=size(tabpos)
numpar = b(2)	; nbre de parametres (1D:5, 2D: 6)
numd = 0 & numf = b(1)-1	; Defaut: afficher toutes les positions
IF KEYWORD_SET(numpos) THEN BEGIN
	numpos = numpos -1	;	compteur de positions demarrant a 0
	IF numpos GE b(1) THEN BEGIN
		numpos = -1
		RETURN
	ENDIF 
	numd = numpos & numf = numpos
ENDIF
;-----------------------------------------------------------------------------

FOR numero = numd, numf DO BEGIN
;     Ecriture du tableau de temps -------------------------------------------
	temp = FINDGEN(posinfo(1, numero)) * pastempo + posinfo(0, numero)
;     Extraction de la partie de tabpos concernant la position ---------------
	tab = reform(tabpos(numero, 0:numpar-1, 0:posinfo(1, numero)-1)) 
;     Selection de l'intervalle de temps a imprimer --------------------------
	c = WHERE(temp GE heures(0) AND temp LE heures(1))
;     Affichage --------------------------------------------------------------
	IF N_ELEMENTS(c) GT 1 THEN BEGIN
		temp = temp(c) & tab = tab(*, c)
		npts = N_ELEMENTS(temp)
		t1 = " H: M: S: MS"
		IF KEYWORD_SET(title) THEN $
		Print, FORMAT='(72("-") / 3X, A12, 6(1X, A9) / 72("-"))', $
					t1, title
		Print, "Position # ", numero
		FOR i = 0, npts-1 DO print, $
			FORMAT='(3X, A12, 6(1X, G9.4))', $
				MSH(temp(i)), tab(0:numpar-1,i)
	ENDIF
ENDFOR
;-----------------------------------------------------------------------------
RETURN
END